A court reading on top of the baseline

Intention

I want to replace a rule inside a new reading while keeping the baseline.

A new reading inherits the baseline and replaces one rule; the baseline itself is untouched.

Correct formFrozen execution sceneBoundary

Incorrect form and why it stays silent

Incorrect form

interpretation CourtReading extends Baseline { status binding; include CourtRule; }

Without exclude the positive support is inherited: on the same facts, Contradiction. Exclusion changes the composition of CourtReading, not Baseline.

Correct form

Arxo Law

language "law.core" version "0.2";
package recipes.z.r02 version "0.1.0";
namespace "urn:recipe:z-interpretations:02";

source Standard { kind standard; jurisdiction "none"; }
edition Edition of Standard { language ru; officiality official; in_force [@2026-01-01, infinity); }
fragment Clause in Edition { kind paragraph; locator "1"; text ru official "Учебная норма допускает два прочтения."; }
entity Person;
relation registered(p: Person);
relation accepted(p: Person);
relation review(p: Person);
rule BaseRule strict { for p: Person; when registered(p); then accepted(p); }
rule CourtRule strict { for p: Person; when registered(p); then not accepted(p); }
rule Review strict { for p: Person; when registered(p); then review(p); }
interpretation Baseline of Clause { status reviewed; include BaseRule; }
interpretation CourtReading extends Baseline { status binding; include CourtRule; exclude BaseRule; }
interpretation_group Meaning { alternatives Baseline, CourtReading; selection any_of; }

Frozen execution scene

Facts and choice	Question	Answer
1. baseline chosen	accepted	TRUE_ONLY / COMPUTED
2. court reading chosen	accepted	FALSE_ONLY / COMPUTED
3. court reading without exclude	accepted	BOTH / COMPUTED
4. without a choice the disputed norm stays silent	accepted	NEITHER / COMPUTED
5. undisputed review remains	review	TRUE_ONLY / COMPUTED

base reading chosen

Arxo Law

test "base reading chosen" {
    given {
        context {
            legal_time @2026-09-13;
            decision_time @2026-09-13T09:00:00+05:00;
            knowledge_time @2026-09-13T09:00:00+05:00;
            timezone "Asia/Almaty";
            interpretation Baseline;
        }
        assert registered(entity_ref("urn:recipe:z-interpretations:02:p"));
    }
    evaluate truth(accepted(entity_ref("urn:recipe:z-interpretations:02:p")));
    expect truth_status == TRUE_ONLY;
    expect evaluation_status == COMPUTED;

}

court reading chosen

Arxo Law

test "court reading chosen" {
    given {
        context {
            legal_time @2026-09-13;
            decision_time @2026-09-13T09:00:00+05:00;
            knowledge_time @2026-09-13T09:00:00+05:00;
            timezone "Asia/Almaty";
            interpretation CourtReading;
        }
        assert registered(entity_ref("urn:recipe:z-interpretations:02:p"));
    }
    evaluate truth(accepted(entity_ref("urn:recipe:z-interpretations:02:p")));
    expect truth_status == FALSE_ONLY;
    expect evaluation_status == COMPUTED;

}

court reading without exclusion

Arxo Law

test "court reading without exclusion" {
    given {
        context {
            legal_time @2026-09-13;
            decision_time @2026-09-13T09:00:00+05:00;
            knowledge_time @2026-09-13T09:00:00+05:00;
            timezone "Asia/Almaty";
            interpretation CourtReading;
        }
        assert registered(entity_ref("urn:recipe:z-interpretations:02:p"));
    }
    evaluate truth(accepted(entity_ref("urn:recipe:z-interpretations:02:p")));
    expect truth_status == BOTH;
    expect evaluation_status == COMPUTED;

}

disputed rule silent without choice

Arxo Law

test "disputed rule silent without choice" {
    given {
        context {
            legal_time @2026-09-13;
            decision_time @2026-09-13T09:00:00+05:00;
            knowledge_time @2026-09-13T09:00:00+05:00;
            timezone "Asia/Almaty";

        }
        assert registered(entity_ref("urn:recipe:z-interpretations:02:p"));
    }
    evaluate truth(accepted(entity_ref("urn:recipe:z-interpretations:02:p")));
    expect truth_status == NEITHER;
    expect evaluation_status == COMPUTED;

}

undisputed consideration stands

Arxo Law

test "undisputed consideration stands" {
    given {
        context {
            legal_time @2026-09-13;
            decision_time @2026-09-13T09:00:00+05:00;
            knowledge_time @2026-09-13T09:00:00+05:00;
            timezone "Asia/Almaty";

        }
        assert registered(entity_ref("urn:recipe:z-interpretations:02:p"));
    }
    evaluate truth(review(entity_ref("urn:recipe:z-interpretations:02:p")));
    expect truth_status == TRUE_ONLY;
    expect evaluation_status == COMPUTED;

}

Counterfactual

Sidecar mutation: exclude BaseRule; → exclude Missing;; expected LDC-E1205. Additional scenes with fragment deletion are marked in the table; the outcome is checked by both evaluators.

Boundary

exclude is local to the reading’s composition. Including undisputed Review in a reading would remove it from the base theory; a binding status alone does not select a reading.

Pitfall

Without exclude, the inherited positive support and the new negative rule meet on the same facts: Contradiction. The baseline itself stays positive.