Accept admissible evidence

Intent

I want to accept support on checkable grounds of admissibility.

The example rules are teaching material, not norms of a force-of-law act.

Wrong form and why it stays silent

// status verified и confidence 0.99 якобы достаточно без проверки подлинности.

A number does not authenticate a document. Rule Accept requires status, a pinned check of the same hash, availability, and currency of the document. evidence_status is a projection relation of the policy, not a numeric confidence function.

Correct form

language "law.core" version "0.2";
package recipes.d.r04 version "0.1.0";
namespace "urn:recipe:d-evidence:04";

entity Person;
entity Record;
relation finding(p: Person) kind empirical;
relation eligible(p: Person) kind institutional;
relation edge(e: Text, d: Text, link: Text);
relation evidence_status(d: Text, state: Text);
relation authentic(d: Text, verifier: Text, outcome: Text);
relation available(d: Text);
relation current(d: Text);
relation accepted(e: Text);
rule Accept strict {
    for e: Text; for d: Text; for link: Text;
    when edge(e,d,link) and evidence_status(d,"verified")
      and authentic(d,"urn:recipe:verifier","verified") and available(d) and current(d);
    then accepted(e);
}
evidence policy Documents {
    profile "law.core.evidence-policy/0.1";
    accepts accepted; protects finding;
    input edge edge; input status evidence_status; input authentic authentic;
    input available available; input current current;
    rule Accept;
}
rule Use strict { for p: Person; when finding(p); then eligible(p); }

Frozen execution scene

In the table P and Q are different entities of the page, C is a case; full identifiers are pinned in the scenes.

Input on 13.09.2026 (a different date is named in the scene)	Question	Answer
all grounds	`truth(eligible(P))`	`TRUE_ONLY` / `COMPUTED`
only status and confidence	`truth(eligible(P))`	`NEITHER` / `COMPUTED`
no document term	`truth(eligible(P))`	`NEITHER` / `COMPUTED`
document not yet known	`truth(eligible(P))`	`NEITHER` / `COMPUTED`

all grounds admit the document

test "all grounds admit the document" {
    given {
        context {
            legal_time @2026-09-13;
            decision_time @2026-09-13T09:00:00Z;
            knowledge_time @2026-09-13T09:00:00Z;
            timezone "UTC";
            evidence_policy Documents;
        }
        evidence Doc: Record {
    status verified; observed_at @2026-09-01T08:00:00Z;
    recorded_at @2026-09-01T09:00:00Z;
    valid [@2026-09-01, @2026-10-01);
    content_hash "sha256:aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa";
}
support Doc supports finding(entity_ref("urn:recipe:d-evidence:04:p"));
verification VDoc { evidence Doc; document_hash "sha256:aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa";
    verifier "urn:recipe:verifier"; outcome verified; recorded @2026-09-02T09:00:00Z;
}
    }
    evaluate truth(eligible(entity_ref("urn:recipe:d-evidence:04:p")));
    expect truth_status == TRUE_ONLY;
    expect evaluation_status == COMPUTED;

}

status and confidence do not admit

test "status and confidence do not admit" {
    given {
        context {
            legal_time @2026-09-13;
            decision_time @2026-09-13T09:00:00Z;
            knowledge_time @2026-09-13T09:00:00Z;
            timezone "UTC";
            evidence_policy Documents;
        }
        evidence Doc: Record {
    status verified; observed_at @2026-09-01T08:00:00Z;
    recorded_at @2026-09-01T09:00:00Z;
    valid [@2026-09-01, @2026-10-01);
    content_hash "sha256:aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa"; confidence 0.99;
}
support Doc supports finding(entity_ref("urn:recipe:d-evidence:04:p"));
    }
    evaluate truth(eligible(entity_ref("urn:recipe:d-evidence:04:p")));
    expect truth_status == NEITHER;
    expect evaluation_status == COMPUTED;

}

missing document term blocks admission

test "missing document term blocks admission" {
    given {
        context {
            legal_time @2026-09-13;
            decision_time @2026-09-13T09:00:00Z;
            knowledge_time @2026-09-13T09:00:00Z;
            timezone "UTC";
            evidence_policy Documents;
        }
        evidence Doc: Record {
    status verified; observed_at @2026-09-01T08:00:00Z;
    recorded_at @2026-09-01T09:00:00Z;

    content_hash "sha256:aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa";
}
support Doc supports finding(entity_ref("urn:recipe:d-evidence:04:p"));
verification VDoc { evidence Doc; document_hash "sha256:aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa";
    verifier "urn:recipe:verifier"; outcome verified; recorded @2026-09-02T09:00:00Z;
}
    }
    evaluate truth(eligible(entity_ref("urn:recipe:d-evidence:04:p")));
    expect truth_status == NEITHER;
    expect evaluation_status == COMPUTED;

}

future record is unavailable

test "future record is unavailable" {
    given {
        context {
            legal_time @2026-09-13;
            decision_time @2026-09-13T09:00:00Z;
            knowledge_time @2026-09-13T09:00:00Z;
            timezone "UTC";
            evidence_policy Documents;
        }
        evidence Doc: Record {
    status verified; observed_at @2026-09-01T08:00:00Z;
    recorded_at @2026-09-20T09:00:00Z;
    valid [@2026-09-01, @2026-10-01);
    content_hash "sha256:aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa";
}
support Doc supports finding(entity_ref("urn:recipe:d-evidence:04:p"));
verification VDoc { evidence Doc; document_hash "sha256:aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa";
    verifier "urn:recipe:verifier"; outcome verified; recorded @2026-09-02T09:00:00Z;
}
    }
    evaluate truth(eligible(entity_ref("urn:recipe:d-evidence:04:p")));
    expect truth_status == NEITHER;
    expect evaluation_status == COMPUTED;

}

The counterfactual program differs only by the mutation named below; its scene:

removed authenticity check admits nothing

test "removed authenticity check admits nothing" {
    given {
        context {
            legal_time @2026-09-13;
            decision_time @2026-09-13T09:00:00Z;
            knowledge_time @2026-09-13T09:00:00Z;
            timezone "UTC";
            evidence_policy Documents;
        }
        evidence Doc: Record {
    status verified; observed_at @2026-09-01T08:00:00Z;
    recorded_at @2026-09-01T09:00:00Z;
    valid [@2026-09-01, @2026-10-01);
    content_hash "sha256:aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa"; confidence 0.99;
}
support Doc supports finding(entity_ref("urn:recipe:d-evidence:04:p"));
    }
    evaluate truth(eligible(entity_ref("urn:recipe:d-evidence:04:p")));
    expect truth_status == TRUE_ONLY;
    expect evaluation_status == COMPUTED;

}

>>> import runpy
>>> check = runpy.run_path("docs/recipes/d-evidence/resources/check.py")
>>> check["check_variant"](https://github.com/arxohq/law/blob/master/docs/recipes/d-evidence/4)
'Д4: контрфактуал подтверждён; lawc = lawref'

>>> import runpy
>>> check = runpy.run_path("docs/recipes/d-evidence/resources/check.py")
>>> check["check_acceptance"](https://github.com/arxohq/law/blob/master/docs/recipes/d-evidence/4)
'Д4: принятие, отчёт и proof проверены; lawc = lawref'

Counterfactual

Diagnostic mutation (check) — LDC-E4702.

Original fragment:

rule Accept strict

Replacement:

rule Accept defeasible

The paired scenes above pin the change of outcome.

Boundary

Choice of verifier is data of the teaching policy. Cryptography is not executed here: verification is a pinned result of an external check. Refusal of support is not a negation of finding.

The counterfactual mutation removes and authentic(d,"urn:recipe:verifier","verified"): a document without a check becomes accepted. That is a weakening of the teaching policy, not a built-in privilege of status verified.

Pitfall

A number does not authenticate a document: without a pinned check of the same hash, availability, and currency, support is refused.

Documentation for Arxo. Writings — blog.arxo.io.

Anonymous visit counts on stats.arxo.io, no cookies.